# aardio 范例: 聊天接口 / 文生图

```aardio
//聊天接口 / 文生图
/*
web.rest.aiChat 用于标准聊天对话接口（ API 端点: v1/chat/completions ）。
通过这个接口识别图像的较常见（视觉模型）, 但生成图像用这个接口的较罕见。

openrouter 的 gemini-2.5-flash-image 使用了这个接口。
下面是使用 web.rest.aiChat 调用该接口的示例。
*/

import console;
console.showLoading(" 正在画图");

//调用 openrouter 的 gemini-2.5-flash-image-preview 画图
import web.rest.aiChat;
var aiClient = web.rest.aiChat(    
    key = "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";
    url = "https://openrouter.ai/api/v1";
    model ="google/gemini-2.5-flash-image-preview";
    temperature = 0.5;
    extraParameters = {
         "modalities": ["image", "text"] //允许生成图像
    }
)   

//构建消息队列
var msg = web.rest.aiChat.message()

//发送提示词（openrouter 的这个模型只能用英文提示词）
msg.prompt("draw a cat");//如果要修改图像，参数 2 指定图像数据或文件路径

//发送绘图请求，参数 2 不要指定流式回调函数（禁用流输出模式）
var resp,err = aiClient.messages(msg);
console.assert(resp,err);

import console
console.dumpJson(resp)

//得到图像 URL
var dataUrl = resp.choices[1].message.images[1].image_url.url;

//解析 data url 格式数据，保存为本地图像文件
import inet.urlData;
var data = inet.urlData.save("/test-gemini-flash.png",dataUrl);

//打开文件
import process.imageView;
process.imageView("/test-gemini-flash.png")
```