aardio 范例: 设置对话框

import win.ui;
/*DSG{{*/
var winform = win.form(text="AI 示例";right=678;bottom=432)
winform.add(
btnSetting={cls="button";text="设置 AI";left=343;top=346;right=627;bottom=395;z=1};
edit={cls="edit";left=39;top=30;right=627;bottom=324;edge=1;multiline=1;z=2}
)
/*}}*/

import fsys.table;
import web.rest.aiChat.settingForm;

// 创建配置文件
var path = io.appData("aardio/temp/test-ai.table");
var config = fsys.table(path);

winform.btnSetting.oncommand = function(id,event){

    // 这些自定义参数都是可选的，可以不设置
    table.assign(config,{
        title = "设置 AI 聊天助手"; // 标题
        f1Title = "设为补全助手"; // 显示 flag1 选项
        f1MultiSelect = false;  // 单选模式
        hyperlink1Title = "超链接"; // key 输入框显示嵌入链接 
        allowKatex = true; // 启用数据公式（Win10 以下总是禁用状态）    
    });

    //可选预定义默认设置（值必须是对象数组）
    table.mix(config,{
        itemData = [{
            url="https://ai.aardio2.com/api/v1";
            key= '\0\1\96';
            model="aardio";
            temperature = 0.1;
            extraParameters = {}; 
        }]  
    });

    //打开 AI 设置窗口，参数 2 指定配置文件
    var frmSetting = web.rest.aiChat.settingForm(winform,config);


    // 可选：用户切换配置时触发
    frmSetting.onSelChange = function(selIndex,configItem){

    }

    // 可选：用户点击链接触发
    frmSetting.onHyperlink = function(apiUrl,apiKey){

    }

    //用户点击了「保存」           
    if( frmSetting.doModal(this) ){

        //获取用户当前选择的配置
        var selectedConfig = config.itemData[config.selItem];

        winform.edit.print(selectedConfig);
    }
}

winform.show();
win.loopMessage();