aardio 范例: COM 接口 - 免注册调用远程桌面控件

设置远程登录参数

//COM 接口 - 免注册调用远程桌面控件
import win.ui;
/*DSG{{*/
var winform = win.form(text="远程桌面客户端";right=599;bottom=799)
winform.add()
/*}}*/

import com.lite;//用于免注册调用 COM 控件
var dll = com.lite("MsTscAx.dll");
var tsc = dll.createEmbedEx(winform,"{7cacbd7b-0d99-468f-ac33-22e495c0afe5}") 

//设置远程登录参数 https://docs.microsoft.com/en-us/windows/win32/termserv/mstscax
tsc.Server = "服务器域名或 IP"; 
tsc.AdvancedSettings2.ClearTextPassword = "登录密码"; //保存密码可省略
tsc.UserName = "Administrator"; //登录用户名
tsc.AdvancedSettings2.EnableCredSspSupport = true; //启用凭据安全服务提供程序(CredSSP)

tsc.AdvancedSettings2.RDPPort = 3389; //端口
tsc.AdvancedSettings2.RedirectPrinters = false; //取消共享打印
tsc.AdvancedSettings2.RedirectDrives = true; //允许共享磁盘

var x,y,cx,cy = win.getScreenPos(winform.hwnd);
tsc.DesktopWidth = cx //远程桌面宽度
tsc.DesktopHeight = cy; //远程桌面高度
tsc.AdvancedSettings2.SmartSizing = true; //自动调整远程桌面大小（当宿主窗口大小改变时）
tsc.FullScreen = true;//启动是否全屏
tsc.FullScreenTitle = winform.text;//全屏标题
tsc.ColorDepth = 32;//32位颜色
tsc.ConnectingText = "正在连接......"

//响应远程桌面事件,控件容器对象是默认的事件监听对象
tsc.OnDisconnected = function(discReason){  
    select (discReason)  {  
        case 2{
            winform.msgbox("已注销登录");  
        }
        else{
            winform.msgbox("远程连接失败");  
        } 
    } 
}  

winform.onEraseBkgnd = lambda() 0;
winform.show(); 

tsc.Connect(); //连接远程桌面

win.loopMessage();