# aardio 范例: BT 下载 / WebView2 纯 HTML 界面
```aardio
//BT 下载 / WebView2 纯 HTML 界面
//win.form 下载界面: https://www.aardio.com/zh-cn/doc/example/Network/Transfer/bt.win.html
//如果 BT 下载没速度，先找个热门种子下载就可以了
import fonts.fontAwesome;
import win.ui;
/*DSG{{*/
var winform = win.form(text="aria2 下载 —— 纯 HTML 界面";right=921;bottom=537)
winform.add()
/*}}*/
import web.view;
var wb = web.view(winform);
//启动 aria2 下载服务进程
import process.aria2;
var aria2 = process.aria2();
aria2.startServer( maxConcurrentDownloads = 10 );
import com.interface.ITaskbarList3;
var taskbar = com.interface.ITaskbarList3.Create();
//导出到网页的接口
wb.external = {
//添加下载任务
addTask = function(url){
if(!#url) return {success=false; error="请输入下载地址或种子文件路径"};
aria2.taskAdd(url,function(gid,err){
if(err){
wb.invoke("onTaskAdded",null,url,err[["message"]]);
}
else {
wb.invoke("onTaskAdded",gid,url,null);
}
});
return {success=true};
};
//获取任务名称
getTaskName = function(gid){
return aria2.taskName(gid);
};
//获取任务路径
getTaskPath = function(gid){
return aria2.taskFilePath(gid);
};
//获取任务URL
getTaskUrl = function(gid){
return aria2.taskUrl(gid);
};
//移除任务
removeTask = function(gid){
aria2.taskRemove(gid);
return true;
};
//暂停任务
pauseTask = function(gid){
aria2.taskPause(gid);
return true;
};
//恢复任务
unpauseTask = function(gid){
aria2.taskUnpause(gid);
return true;
};
//浏览文件
exploreFile = function(path){
if(#path) raw.explore(path,"/select");
return true;
};
//复制链接
copyLink = function(url){
import win.clip;
win.clip.write(url);
return true;
};
//格式化文件大小
formatSize = function(size){
import math.size64;
return math.size64(size).format();
};
//获取任务状态
getTaskStatus = function(gid){
return aria2.tellStatus(gid,"status");
};
};
//监听 aria2 事件
aria2.onDownloadStart = function(task){
wb.invoke("onDownloadStart",task.gid);
}
aria2.onDownloadPause = function(task){
wb.invoke("onDownloadPause",task.gid);
}
aria2.onDownloadStop = function(task){
wb.invoke("onDownloadStop",task.gid);
}
aria2.onDownloadComplete = function(task){
if(aria2.taskIsTorrent(task.gid)){
wb.invoke("onTorrentComplete",task.gid);
}
else{
wb.invoke("onDownloadComplete",task.gid);
/*
//aria2 会话不会自动保存已完成任务（重启不恢复），可用以下代码保存：
var downloadedFiles = table.append(downloadedFiles,{
gid = task.gid;//重启后 gid 无效
name = aria2.taskName(task.gid);
url = aria2.taskUrl(task.gid);
path = aria2.taskFilePath(task.gid);
});
var path = io.joinpath(aria2.saveSessionPath,"downloadedFiles.table");
JSON.save(path,downloadedFiles)
*/
}
}
aria2.onDownloadError = function(task){
var errMsg = aria2.taskErrorMessage(task.gid);
wb.invoke("onDownloadError",task.gid,errMsg);
}
//更新下载进度
updateDownloadStatus = function(init){
aria2.tellActive(function(result,err){
if(result) {
var totalLength,completedLength = math.size64(),math.size64();
var progressData = {};
for(k,v in result){
totalLength.add(v.totalLength);
completedLength.add(v.completedLength);
progressData[v.gid] = {
downloadSpeed = tonumber(v.downloadSpeed) : 0;
totalLength = tonumber(v.totalLength) : 0;
completedLength = tonumber(v.completedLength) : 0;
connections = v.connections;
status = v.status;
};
}
wb.invoke("updateProgress",progressData);
//显示所有下载任务的总进度
var pos = (completedLength / totalLength) * 100;
if(pos >= 0 && pos <= 100){
taskbar.SetProgressValue(winform.hwnd,pos,100);
}
}
},"gid","status","connections","downloadSpeed","totalLength","completedLength");
if(init){
aria2.tellWaiting(0,20,function(result,err){
if(result) {
var progressData = {};
for(i,v in result){
progressData[v.gid] = {
downloadSpeed = tonumber(v.downloadSpeed) : 0;
totalLength = tonumber(v.totalLength) : 0;
completedLength = tonumber(v.completedLength) : 0;
connections = v.connections;
status = v.status;
};
}
wb.invoke("updateProgress",progressData);
}
},"gid","status","connections","downloadSpeed","totalLength","completedLength");
}
}
//错误处理
aria2.onError = function(errMsg,rpcErr){
wb.invoke("showError",errMsg);
}
wb.html = /**
**/
winform.show();
//启动就绪执行
aria2.ready(
function(){
updateDownloadStatus(true);
winform.setInterval(updateDownloadStatus,1500);
}
)
winform.onDestroy = function(){
//退出前务必关闭 aria2 并保存会话，下次启动才能恢复状态
aria2.stop();
}
win.loopMessage();
```