aardio 范例: 快速入门 - 第一个 aardio 程序

语法速览 | 特殊符号大全 | 模式匹配入门 | 魔法 web.rest | 创建窗口控件 | plus 控件入门

//快速入门
import win.ui;
/*DSG{{*/
var winform = win.form(text="快速入门 - 第一个 aardio 程序";right=757;bottom=467)
winform.add(
edit={cls="richedit";left=6;top=6;right=754;bottom=464;db=1;dl=1;dr=1;dt=1;edge=1;link=1;multiline=1;vscroll=1;z=1}
)
/*}}*/

//导入 JSON 库，文本框就能以 JSON 格式输出对象
import JSON;

//文本框内输出任意对象
winform.edit.print({
    rawString = "双引号内是原样字符串，编译时反斜杆是普通字符";
    backslashEscapedString  = '单引号内在编译时处理转义符（反斜杠）。例如回车换行\r\n';
    longRawString = /*
注释可以赋值为字符串:

语法速览: https://www.aardio.com/zh-cn/doc/guide/language/syntax-quick-ref.html
特殊符号大全: https://www.aardio.com/zh-cn/doc/guide/language/special-characters.html
模式匹配入门: https://www.aardio.com/zh-cn/doc/guide/language/pattern-matching.html
魔法 web.rest: https://www.aardio.com/zh-cn/doc/library-guide/std/web/rest/client.html
创建窗口控件: https://www.aardio.com/zh-cn/doc/library-guide/std/win/ui/create-winform.html
plus 控件入门: https://www.aardio.com/zh-cn/doc/library-guide/std/win/ui/ctrl/plus.html
*/;
    array = [1,2,3,4,5,6,7];//纯数组，数据类型也是表（table）
    object = { //对象（表）
        name = "object";
        value = { 
            object = {
                name = "object.object"
            }
        }
    };
    jsLikeObject = {
        "namve":"value","array":[1,2,3]
    };
    buffer = raw.buffer("二进制字节串");
    pointer = topointer(1);//原生指针
    time = time.now();//日期时间
    boolean = true || false;//布尔值
    number = 123; //数值，64 位浮点数
    ulong64 = math.size64(); //无符号 64 位整数
});

//继续打印，不会覆盖之前的内容。
winform.edit.print("《 aardio 入门 》
https://www.aardio.com/zh-cn/doc/quickstart
");

//定义一个回调函数，在richedit 控件中点击链接时自动触发此函数。 
winform.edit.onHyperlink = function(message,href){

    if( message = 0x202/*_WM_LBUTTONUP*/ ) {
        raw.execute(href);
    }
}

winform.show();
win.loopMessage();