aardio 范例: 客户端

import console;
import web.dav.client;

// 创建客户端
var dav = web.dav.client("http://localhost:8081");

//不指定参数匿名登录
if(! dav.login("admin", "123456")  ){
    console.fail("登录失败!");
    console.pause();
    return;
}

/*
列出根目录，
注意始终要写相对于 URL 根路径的完整路径。
调用方不需要也不能对文件名进行 URL 编解码（web.dav.client 会自动处理）。
*/
var resources,err = dav.list("/");
if(resources){
    for(i=1; #resources; 1){
        var r = resources[i];
        console.log(r.path, r.isCollection ? "[目录]" : "[文件]"); 
    }
}

// 创建目录（以斜杠结束的路径表示目录）
var ok,err = dav.mkdir("/newFolder/");
console.log("创建目录:",ok,err);

//写入文件
var ok,err = dav.put("/test.txt", "Hello WebDAV!");
console.log(ok,err)

//读取文件
var data, status = dav.get("/test.txt");
console.log("下载内容:", data);

//大文件下载
/***
var onReceive = function(receivedSize,totalSize){
    console.log("正在下载",receivedSize,totalSize)  
}
var ok,err = dav.download(
    "/example.mp4", //服务器路径
    "/example.mp4", //本地路径
    onReceive
);
console.log(ok, status)
***/

//大文件上传（支持断点续传类工具）
/***
var onReceive = function(sentSize,totalSize){
    console.log("正在上传",sentSize,totalSize)  
}
var ok,err = dav.upload(
    "/example.mp4", //服务器路径
    "example.mp4", //本地路径
    /*lockToken*/,
    onReceive
);
console.log(ok, status)
***/

// 复制文件
dav.copy("/test.txt", "/test_copy.txt");

// 移动/重命名
dav.move("/test_copy.txt", "/renamed.txt");

// 锁定文件
var token,err = dav.lock("/test.txt", "myApp");
if(token){
    // 使用锁令牌更新文件
    dav.put("/test.txt", "Updated content", token);
    // 解锁
    dav.unlock("/test.txt", token);
}

// 删除
dav.delete("/test.txt");

console.pause();