aardio 范例: 按 CTRL + N 或 ALT + C

//窗口快捷键
import win.ui;
/*DSG{{*/
var winform = win.form(text="按 CTRL + N 或 ALT + C";right=759;bottom=469)
winform.add()
/*}}*/

import win.ui.accelerator;
var accelerator = win.ui.accelerator([

    { 
        ctrl = true; vkey = 'N'#; 
        oncommand = function() winform.msgbox("CTRL+N"); 
    };  

    { 
        alt = true; vkey = 'C'#; 
        oncommand = function() winform.msgbox("ALT+C"); 
    };  

],winform );

/*
win.ui.accelerator 创建的快捷键限于指定窗口内生效。

var accelerator = win.ui.accelerator( accTable,winform )
上述代码创建快捷键时有两个参数，参数 accTable 应该是一个指定快捷键的数组。

每一个快揵键使用以下字段指定快捷键的属性:

- ctrl 字段如果为 true 则要求同时按下 Ctrl 键。
- alt 字段如果为 true 则要求同时按下 Alt 键。
- shift 字段如果为 true 则要求同时按下 Shift 键。
- vkey 字段指定虚拟键码，虚拟键码参考标准库里的 key.VK ，可使用_VK 前缀的常量指定，普通字符键用大写的字节码指定
- cmd 字段指定快捷键触发的命令 ID，如果指定了 oncommand 可以省略 cmd 字段
- oncommand 如果指定一个响应快捷键的事件，则会自动调用 winform.registCommand() 生成 cmd 的值

win.ui.accelerator在绑定窗体时，
会添加 winform.preTranslateAccelerator() 事件用于拦截快捷键消息并响应事件。
*/

winform.show(); 
win.loopMessage();