# aardio 范例: 用 web.rest 客户端调用 HTTP API - 设置 HTTP 头



```aardio
//用 web.rest 客户端调用 HTTP API - 设置 HTTP 头

import crypt;
import web.rest.jsonLiteClient;

var http = web.rest.jsonLiteClient();  

//设置默认添加到所有请求的 HTTP 头
http.addHeaders = { ["X-Auth-Token"] = "自定义 Token" }

//如果 addHeaders 是表则添加所有请求都要添加的 HTTP 头，否则替换请求头。
http.setHeaders({
	["Test"] = "test"
})

//使用默认的 Authorization 请求头指定 token 
http.setAuthToken("token");

/*
如果每次请求都要修改HTTP头，可以写到这个事件里.
*/
http.beforeRequestHeaders = function(params){
	var apiKey = "";
	var secretKey = ""; 
	var authorization = {
		["apiKey"] = apiKey;
		["time"] = tonumber(time()); 
	}
	
	authorization["sign"] = crypt.md5(apiKey ++ secretKey ++ authorization.time)
	
	//通过返回值设置本次请求的HTTP头, Content-Type不需要指定（会自动指定）
	return {
		["Authorization"] = crypt.encodeBin(JSON.stringify(authorization)) 
	}; 
}

var api = http.api("http://httpbin.org/anything");

var jsonData = api.post({
	用户名 = "用户名";
	密码 = "密码";
})

import console;
console.dumpJson(jsonData)
console.pause(true);
```