Select 选择器

Select 用于从下拉列表中选择一个值。

示例：

import win.ui;
/*DSG{{*/
var winform = win.form(text="AntdUI Select";right=520;bottom=260)
winform.add(
host={cls="custom";edge=1;left=40;top=40;right=300;bottom=80;z=1}
)
/*}}*/

import dotNet.AntdUI;

// 创建扩件
var sel = AntdUI.Select(winform.host);

// 空值默认提示
sel.PlaceholderText = "请选择水果";

// 直接添加字符串数组
sel.addItems(["苹果","香蕉"])

// 也可以添加数组的数组，子数组格式为 [显示名称,数据值]
sel.addItems([
    ["苹果 / apple", "apple"],
    ["香蕉 / banana", "banana"]
])

sel.SelectedIndex = 0;

sel.SelectedIndexChanged = function(sender,e){
    // sel.SelectedIndex 为 .NET 索引，从 0 开始
    winform.text = sel.SelectedValue;
}

winform.show();
win.loopMessage();

sel.addItems 这个方法要小写首字母，这暗示它是由 aardio 扩展并新增的函数。

.NET 方法通常小写方法名的首字母，而 aardio 通常小写方法名的首字母。

如果不使用 addItems 方法，则必须如下逐个添加字符串或者 ntdUI.SelectItem(text,value) 对象：

import win.ui;
/*DSG{{*/
var winform = win.form(text="AntdUI Select";right=520;bottom=260)
winform.add(
host={cls="custom";edge=1;left=40;top=40;right=300;bottom=80;z=1}
)
/*}}*/

import dotNet.AntdUI;
var sel = AntdUI.Select(winform.host);

sel.Items.Add( AntdUI.SelectItem("苹果", "apple") );
sel.Items.Add( AntdUI.SelectItem("香蕉", "banana") );
sel.SelectedIndex = 0;

winform.show();
win.loopMessage();

常用属性

• Items：选项集合。
• SelectedIndex：当前选项索引，通常从 0 开始。
• SelectedValue：当前选中值。
• PlaceholderText：占位提示。
• AllowClear：允许清除。
• ListAutoWidth：下拉列表自动宽度。

注意

AntdUI.SelectItem 当前 DLL 常用构造为：

var item = AntdUI.SelectItem("显示文本", "绑定值");

Markdown 格式