dotNet.ReoGrid 扩展库 - 事件

工作簿事件

操作事件

工作表事件

工作表事件适用于工作表实例。要获取工作表实例，可以使用工作簿(表格控件)的 CurrentWorksheet 或 Worksheets[index] 属性。参考工作表文档。

单元格事件

关于单元格编辑事件的更多信息，请参考单元格编辑。

键盘事件

行和列事件

区域事件

边框事件

选择事件

了解更多关于选择的信息。

大纲事件

关于大纲事件的使用，请参考分组与大纲。

冻结事件

了解更多关于冻结的信息，请参考冻结。

通用事件

剪贴板事件

示例代码

响应鼠标右键事件，在 ReoGrid 控件内调用 aardio 创建右键菜单 #

import win.ui;
import win.ui.menu;
/*DSG{{*/
var winform = win.form(text="ReoGrid - 右键弹出菜单")
winform.add()
/*}}*/

import dotNet.ReoGrid; 
var grid = ReoGrid.ReoGridControl(winform);
var sheet1 = grid.CurrentWorksheet;

sheet1["B2:D4"] =  [ 
    [ "测试", "测试2" ],
    [ "测试3", "测试4" ],
];

//鼠标按键枚举
var MouseButtons = ReoGrid.Interaction.MouseButtons;

sheet1.CellMouseUp = function(sender, e) {

    // 判断是否是鼠标右键弹起 
    if (e.Buttons === MouseButtons.Right/*0x200000*/ ) {

        //获取被点击的单元格位置
        var cellPos = e.CellPosition;
        if (!cellPos.IsEmpty){

            //创建弹出菜单
            var popmenu = win.ui.popmenu(winform);

            //添加菜单项
            popmenu.add('演示',function(id){
                //在下面输入菜单响应代码

                // 获取当前选区范围（返回 ReoGrid.RangePosition 对象）
                var range = sheet1.SelectionRange;

                //获取当前选中的单元格数据
                var cellData = sheet1[cellPos]; 
                //winform.msgbox("选中的单元格数据：" + cellData);

                //也可以这样写
                winform.msgbox("选中的单元格数据：" + e.Cell.Data);
            });

            //弹出右键菜单
            popmenu.popup();
        }
    }
};


winform.show();
win.loopMessage();

ReoGrid 的所有事件回调参数都一样，都有(sender, e)这两个回调参数。 e 都是继承自 System.EventArgs 的对象。

对于 sheet1.CellMouseUp 这样的单元格鼠标事件，e 是一个 ReoGrid.Events.CellMouseEventArgs 对象（继承自 System.EventArgs ），继承自 ReoGrid.Events.WorksheetMouseEventArgs 对象, 增加了 Cell，CellPosition 等与单元格有关的字段。细节请参考 ReoGrid.Events 事件对象源码

通过 e.AbsolutePosition 获取到的点击坐标并不是相对于控件左上角，而是相对于第一个单元格的左上角。我们可以使用 aardio 代码 var x,y = win.getMessagePos() 得到最后一次鼠标消息的屏幕坐标，然后使用 popmenu.popup(x,y,true/*表示屏幕坐标*/) 就可以在该位置弹出右键菜单。更简单的方法是不写参数，直接写 popmenu.popup() 由 aardio 会自动获取最后一次鼠标消息的位置坐标作为参数。

使用 win.ui.popmenu 前必须调用 import win.ui.menu 导入菜单支持库。

请单考 单元格鼠标事件

通过事件处理设置可编辑区域

ReoGrid 提供的许多前置事件都有 IsCancelled 属性，可以设置为 true 来通知控件取消后续操作。这通常用于阻止单元格编辑或大纲折叠/展开操作。

例如，只允许在指定区域内编辑文本：

import win.ui;
/*DSG{{*/
var winform = win.form(text="ReoGrid 图表示例")
/*}}*/

import dotNet.ReoGrid;
var grid = ReoGrid.ReoGridControl(winform);
var sheet1 = grid.CurrentWorksheet;

// 导入 ReoGrid 库
import dotNet.ReoGrid;

// 获取当前工作表
var sheet1 = grid.CurrentWorksheet;

// 定义可编辑区域 
var editableRange = ReoGrid.RangePosition("B3:D4");

//创建样式。注意 dotNet.ReoGrid 扩展库需要升级到最新版，不然无参数时返回值为是 null 。
var style = ReoGrid.WorksheetRangeStyle()
style.Flag = ReoGrid.PlainStyleFlag.BackColor
style.BackColor = ReoGrid.Graphics.SolidColor.SkyBlue
sheet1.SetRangeStyles(editableRange, style);// 为指定区域设置天蓝色背景

// 设置提示文本
sheet1["B3"] = "仅允许在此范围内编辑:";

// 处理 BeforeCellEdit 事件
sheet1.BeforeCellEdit = function(sender, e) { 
    // 如果单元格不在可编辑范围内，则取消编辑
   e.IsCancelled =  !editableRange.Contains(e.Cell.Position) 
} 

winform.show();
win.loopMessage();

aardio 使用说明：

1. 在 aardio 中，事件处理函数可以直接赋值给事件属性
2. Ranges["B3:D4"] 使用 Excel 风格的区域表示法，更直观
3. 事件参数 e 包含丰富的上下文信息，如 e.Cell 获取当前单元格
4. 通过设置 e.IsCancelled = true 可以取消默认操作

Markdown 格式