aardio 范例: 完整示例

import console;
import string.wordsSegmenter;

var segmenter,err = string.wordsSegmenter("zh-Hans-CN");
if(!segmenter){
    console.error(err);
    console.pause();
    return;
}

var text = "我爱北京和上海，Hello world! 👋";
console.log("原文：",text);
console.log("请求语言：",segmenter.language);
console.log("实际规则：",segmenter.resolvedLanguage);

var words,err = segmenter.getWords(text);
if(words === null) console.error(err);
else console.dump(words);

var tokens,err = segmenter.getTokens(text);
if(tokens === null) console.error(err);
else {
    console.log("词文本 / 0 起始 UTF-16 位置 / UTF-16 长度");
    for i,token in tokens {
        console.log(token.text,token.startPosition,token.length);
    }
}

var en,err = string.wordsSegmenter("en-US");
if(!en){ console.error(err); console.pause(); return; }

// 索引 5 是逗号，返回后面的 world。
var token,err = en.getTokenAt("hello, world! ",5);
console.dump(token);
console.error(err);

// 查看 Windows 提供的数字、日期、时间等替代形式。
var normalized,err = en.getTokens("1234.50 at 10:30 AM on 12/25/2026");
console.dump(normalized);
console.error(err);

console.pause();